Status YM
Masih proses streaming, mohon tunggu sebentar... :D
.

English French German Spain Italian Dutch Russian Portuguese Japanese Korean Arabic Chinese Simplified
 

Jumat, 26 November 2010

Tips Agar Komputer Lambat Menjadi Garang Kembali


Masalah kritis yang bikin komputer menjadi lemot (lambat banget):

1. registry mungkin dah amburadul
2. dma (direct memory access)mode telah berubah menjadi PIO (Processor Input Oputput)mode karena keseringan hang ato error, sehingga program tidak mengandalkan memory lg ttp memaksa kerja prosesor kerja bit per bit (mencapai 100 persen yg bisa bikin kompi panas bgt). Setiap crash/error DMA mode turun dr Ultra DMA mode 5.. 4.. 3.. hingga PIO. 6x crash = lemot.

Solusi yang disarankan :
1. instal CC Cleaner
atau RegCure scan lalu fix problems.
2. masuk : control panel - system - hardware - device manager - IDE ATA/ATAPI controller - Primary IDE Channel - (klik 2x) - Advanced Setting - Device 0 dan Device 1 transfer modenya ubah mjd : DMA if available - OK.

Kalau masih lambat/hang, download resettingdma.vbs
' Visual Basic Script program to reset the DMA status of all ATA drives

' Copyright © 2006 Hans-Georg Michna

' Version 2007-04-04

' Works in Windows XP, probably also in Windows 2000 and NT.
' Does no harm if Windows version is incompatible.

If MsgBox("This program will now reset the DMA status of all ATA drives with Windows drivers." _
& vbNewline & "Windows will redetect the status after the next reboot, therefore this procedure" _
& vbNewline & "should be harmless.", _
vbOkCancel, "Program start message") _
= vbOk Then

RegPath = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Contr ol\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}\"
ValueName1Master = "MasterIdDataChecksum"
ValueName1Slave = "SlaveIdDataChecksum"
ValueName2Master = "UserMasterDeviceTimingModeAllowed"
ValueName2Slave = "UserSlaveDeviceTimingModeAllowed"
ValueName3 = "ResetErrorCountersOnSuccess"
MessageText = "The following ATA channels have been reset:"
MessageTextLen0 = Len(MessageText)
ConsecutiveMisses = 0
Set WshShell = WScript.CreateObject("WScript.Shell")

For i = 0 to 999
RegSubPath = Right("000" & i, 4) & "\"

' Master

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Master
errMaster = Err.Number
On Error Goto 0
If errMaster = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Master
WshShell.RegDelete RegPath & RegSubPath & ValueName2Master
On Error Goto 0
MessageText = MessageText & vbNewLine & "Master"
End If

' Slave

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Slave
errSlave = Err.Number
On Error Goto 0
If errSlave = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Slave
WshShell.RegDelete RegPath & RegSubPath & ValueName2Slave
On Error Goto 0
If errMaster = 0 Then
MessageText = MessageText & " and "
Else
MessageText = MessageText & vbNewLine
End If
MessageText = MessageText & "Slave"
End If

If errMaster = 0 Or errSlave = 0 Then
On Error Resume Next
WshShell.RegWrite RegPath & RegSubPath & ValueName3, 1, "REG_DWORD"
On Error Goto 0
ChannelName = "unnamed channel " & Left(RegSubPath, 4)
On Error Resume Next
ChannelName = WshShell.RegRead(RegPath & RegSubPath & "DriverDesc")
On Error Goto 0
MessageText = MessageText & " of " & ChannelName & ";"
ConsecutiveMisses = 0
Else
ConsecutiveMisses = ConsecutiveMisses + 1
If ConsecutiveMisses >= 32 Then Exit For ' Don't search unnecessarily long.
End If
Next ' i

If Len(MessageText) <= MessageTextLen0 Then
MessageText = "No resettable ATA channels with Windows drivers found. Nothing changed."
Else
MessageText = MessageText & vbNewline _
& "Please reboot now to reset and redetect the DMA status."
End If

MsgBox MessageText, vbOkOnly, "Program finished normally"

End If ' MsgBox(...) = vbOk

' End of Visual Basic Script program

Teknisnya sih bukan didonload, tetapi di copas (copy dan paste) semua isi textnya ke notepad (klik start> Run> ketik notepad).
Lalu setelah direname .txt jadi .vbs, iconnya tidak notepad lagi, tetapi icon VBscript file. pada saat rename, jangan lupa kosongkan centang untuk Hide ekstensions for known file types di folder option - view.



Jika ikonnya sudah berubah, klik 2x resetdma.vbs dan akan muncul dialog box yang isinya menyarankan restart.
Setelah restart baru terasa performanya.
sebelum klik 2x Silahkan non aktifkan antivirus anda untuk sementara, antivirus anda akan mendeteksi sebagai malicious file karena script modifikasi registry.

Cara ini juga membuat komputer lama yang lambat dan terlalu banyak program serasa kompi baru lagi.

Saya pakai notebook Compaq Presario M2000 CentrinoM 1,7 GHz, 512 mb. Setelah resetting DMA bisa multitask firefox (14 tab), YM(3 login), 2 windows explorer, tv home media (tuner), coreldraw 12, word, photoshop dan winamp, dan kerja prosesor tidak sampai 48 persen.

Selamat mencoba...

PERHATIAN:
Segala Kerusakan yang ditimbulkan akibat salah melakukan proses ditanggung sendiri, karena penulis sudah mempraktekan trik tersebuta dan berhasil.




Enter your Email address: Delivered by FeedBurner

Baca juga yang ini :


Stumble
Delicious
Technorati
Twitter
Facebook

0 komentar:

Posting Komentar

Video

Langganan

Enter your Email address:

Delivered by FeedBurner

 
INTERNETAN SEPUASNYA 24 JAM NONSTOP, CEPAT, STABIL HANYA 80 RIBU/BULAN CALL 0812-1166-7511.*** LAPTOP/KOMPUTER KESAYANGAN ANDA BERMASALAH? CALL 0812-1166-7511. BAGI PELANGGAN KDW HOTSPOT GRATIS PASANG IKLAN DI INTERNET

KDW HOTSPOT | SOLUSI INTERNET MURAH CEPAT DAN STABIL Copyright © 2010 LKart Theme is Designed by Lasantha